XProfan

 $H windows.ph
'###############################################
'TWJpeg.Dll - Interface (angepaßt von Dietmar Horn)
'Freeware-Dll
'Speziell für Jpg-Files und Profan²
'Da einige Jpg-Files von der Nviewlib nicht geladen
'werden koennen wurde diese Dll entwickelt.
'Unterstützung für :
'                   JPG,JPEG
'                   Twain-Geräte ( Scanner - Kamera )
'                   externe Module (Dll,EXE)
'                   progressiv und normal gespeicherte Jpg's
'Lädt und speichert Jpg-Bitmaps
'                   progressiv oder normal
'                   mit Angabe der Kompressions-Qualität
'###############################################
'Teil-Funktionen der DLL
'###############################################
DEF TWJ_LoadJpeg(3) ! "TwJpeg.dll","TWJ_LoadJpeg"
'Parameter :
'1 = Zeiger auf Filename
'2 = Zeiger auf LongInt der die Breite aufnimmt
'3 = Zeiger auf LongInt der die Höhe aufnimmt
'Rueckgabe = Bitmap-Handle
'###############################################
'API-Hilfsfunktionen
DEF SelectObject(2) ! "gdi32","SelectObject"
DEF DeleteObject(1) ! "gdi32","DeleteObject"
DEF CreateCompatibleDC(1) ! "gdi32","CreateCompatibleDC"
DEF StretchBlt(11)  ! "gdi32","StretchBlt"
DEF DeleteDC(1)     ! "gdi32","DeleteDC"
'Globale Deklarationen
Declare Image#,Breite#,Hoehe#

Proc StretchLoad_Jpg

    'Laedt ein JPG-Bitmap ins Hauptfenster
    'verhält sich wie LoadSizedBmp
    Parameters Filename$,X&,Y&,W&,H&
    Declare Jpg_Handle&,MemDC&,Bild&
    Dim Image#,260
    Dim Breite#,4
    Dim Hoehe#,4
    String Image#,0 = Filename$
    Let Jpg_Handle& = TWJ_LoadJpeg(Image#,Breite#,Hoehe#)
    Let MemDC& = CreateCompatibleDC(%HDC)
    Let Bild& = SelectObject(MemDC&,Jpg_Handle&)
    StretchBlt(%HDC,  X&, Y&, W&, H&, MemDC&, 0, 0, Long(Breite#,0), Long(Hoehe#,0), $CC0020)
    StretchBlt(%HDC2, X&, Y&, W&, H&, MemDC&, 0, 0, Long(Breite#,0), Long(Hoehe#,0),$CC0020)
    DeleteDC(MemDC&)
    DeleteObject(Bild&)
    DeleteObject(Jpg_Handle&)
    Dispose Image#
    Dispose Breite#
    Dispose Hoehe#

EndProc

'Beispiel :
cls
~SetClassLong(%hwnd, ~GCL_STYLE, (~GetClassLong(%hwnd, ~GCL_STYLE)- ~CS_HREDRAW - ~CS_VREDRAW))
StretchLoad_Jpg "ELK.JPG",0,0,@Width(%hwnd),@Height(%hwnd)

while 1

    waitinput
    case %key=2:BREAK
    case %key=4:StretchLoad_Jpg "ELK.JPG",0,0,@Width(%hwnd),@Height(%hwnd)

Wend

end