XProfan

WindowTitle "Einfacher, schneller Single Precision Pseudo-Random Generator"
' Rechtliches: Teilauszug aus ACM-Algo. Nr. 359 by John Burghardt
' Details und Referenzen siehe Anhang weiter unten! OHNE GEWÄHR!
Cls
declare seed&
seed&=12345
print
print " SOLL        12345   0.096616  207482415"
print seed&,r_uniform_01(),seed&
print
print " SOLL     207482415  0.833995  1790989824"
print seed&,r_uniform_01(),seed&
print
print " SOLL    1790989824  0.947702  2035175616"
print seed&,r_uniform_01(),seed&
print
waitinput
End

Proc r_uniform_01

    DECLARE k&,r_uniform_01!'extern_global: seed&
    k& = seed& \ 127773
    seed&= 16807*(seed&-k&*127773)-k&*2836
    case  seed&<0:seed&=seed&+2147483647
    return seed&*val("4.656612875e-10")

endproc

' *******************************************************************************
' R_UNIFORM_01 returns a unit SINGLE PRECISION pseudorandom number.
' This routine implements the recursion
'   seed = 16807 * seed mod (2^31-1)
'   r_uniform_01 = seed/(2^31-1)
' The integer arithmetic never requires more than 32 bits including a sign bit.
'
' If the initial seed is 12345, then the first three computations are
'       Input     Output      R_UNIFORM_01
'       SEED      SEED
'          12345   207482415  0.096616
'      207482415  1790989824  0.833995
'     1790989824  2035175616  0.947702
'
' Modified: 11 August 2004  Author: John Burkardt
' Reference:
'     Paul Bratley, Bennett Fox, L E Schrage,
'     A Guide to Simulation,
'     Springer Verlag, pages 201-202, 1983.
'
'     Pierre L'Ecuyer,
'     Random Number Generation,
'     in Handbook of Simulation,
'     edited by Jerry Banks,
'     Wiley Interscience, page 95, 1998.
'
'     Bennett Fox,
'     Algorithm 647:
'     Implementation and Relative Efficiency of Quasirandom
'     Sequence Generators,
'     ACM Transactions on Mathematical Software,
'     Volume 12, Number 4, pages 362-376, 1986.
'
'     P A Lewis, A S Goodman, J M Miller,
'     A Pseudo-Random Number Generator for the System/360,
'     IBM Systems Journal,
'     Volume 8, pages 136-143, 1969.
'
'   Parameters:
'
'     Input/output, integer SEED, the "seed" value, which should NOT be 0.
'     On output, SEED has been updated.
'
'     Output, real R_UNIFORM_01, a new pseudorandom variate,
'     strictly between 0 and 1.
'     Although SEED can be represented exactly as a 32 bit integer,
'     it generally cannot be represented exactly as a 32 bit real number!