XProfan

WindowTitle "    J A G '   D E N   W U M P U S"
WindowStyle 24
CLS
Font 2
Randomize
Declare RO&[20,3],LO&[20],WPOS&
declare i&,j&,T&,i$,k$
Declare L&,ARROWS&,DATA$

Proc MON :parameters x&

    return (X&=LO&[RO&[L&,1]]) OR (X&=LO&[RO&[L&,2]]) OR (X&=LO&[RO&[L&,3]])

Endproc

Proc CHK :parameters x&

    return (X&=RO&[L&,1]) OR (X&=RO&[L&,2]) OR (X&=RO&[L&,3])

EndProc

Proc FLUTTER

    Repeat

        L&=RND(19)+1

    UNTIL I&<>L&

EndProc

' Erzeuge das Höhlensystem:
DATA$="2,6,5,3,8,1,4,10,2,5,2,3,1,14,4,15,1,7,17,6,8,7,2,9,18,8,10,9,3,11"+\
"19,10,12,11,4,13,20,12,14,5,11,13,6,16,14,20,15,17,16,7,18,17,9,19,18,11,20,19,13,16"

Whileloop 20:i&=&Loop

    LO&[I&]=0

    Whileloop 3:j&=&Loop

        RO&[I&,J&]=Val(Substr$(Data$,3*(i&-1)+j&,","))

    Endwhile

Endwhile

WPOS&=RND(19)+2
LO&[WPOS&]=1

Whileloop 2,5:i&=&Loop

    Repeat

        T&=RND(19)+2

    UNTIL LO&[T&]=0

    LO&[T&]=I&

Endwhile

START:
ARROWS&=5'Anzahl Pfeile
L&=1'Start-Location = Höhle 1
CLS 0
' Hauptschleife

WHILE 1

    case %csrlin>12:cls 0
    color 10,0
    PRINT
    PRINT "  Du bist in Höhle ";L&;"."
    PRINT "  Tunnels führen zu den Höhlen ";RO&[L&,1];", ";RO&[L&,2];" und ";RO&[L&,3];"."
    PRINT
    color 0,14
    Case MON(1):PRINT "  In der Nähe stinkt etwas bestialisch!"
    Case MON(2) OR MON(3):PRINT "  Du hörst etwas flattern."
    Case MON(4) OR MON(5):PRINT "  Ein eiskalter Wind bläst aus einer angrenzenden Höhle."
    color 3,13
    PRINT "  Pfeil schiessen oder weiterMarschieren? [S,M]"

    Repeat

        K$=Upper$(GETKEY$())

    UNTIL (K$="S") OR (K$="M")

    print

    IF K$="M"' Move

        color 0,15
        print "  Zu Höhle Nr. ?",:INPUT I&
        print

        IF CHK(I&)

            L&=I&

        ELSE

            PRINT "  Geht nicht."

        ENDIF

    ELSE' Shoot

        color 2,14
        PRInt "  In welche Höhle schießen?",:INPUT I&
        print

        IF CHK(I&)

            IF LO&[I&]=1

                color 4,11
                PRINT "  DU HAST DAS WUMPUS-MONSTER ERLEGT!"
                PRINT "  Gratulation, du hast gewonnen!"
                BREAK

            ELSE

                color 11,4
                PRINT "  Pfeile treffen nicht so genau -"
                print "  versuche es in einer anderen Höhle..."

                IF RND(4)<3

                    color 5,12
                    PRINT "  Du hast den Wumpus geweckt und vertrieben."
                    LO&[WPOS&]=0:WPOS&=RO&[WPOS&,RND(2)+1]:LO&[WPOS&]=1

                ENDIF

                Dec ARROWS&

                IF ARROWS&=0

                    color 12,5
                    PRINT "  Du hast leider keine Pfeile mehr!"
                    BREAK

                Endif

            ENDIF

        ELSE

            color 0,15
            PRINT "  Nicht possibile."

        ENDIF

    ENDIF

    SELECT LO&[L&]

        CASEof 1:color 13,2:PRINT "  Der Wumpus hat dich soeben GEFRESSEN!":BREAK

        CASEof 2,3:color 2,13:PRINT "  Eine Riesenfledermaus trägt dich woanders hin!":I&=L&

        FLUTTER
        OTHERWISE

    ENDSELECT

    IF (LO&[L&]=4) OR (LO&[L&]=5)

        color 4,10
        PRINT "  Du fällst ins Bodenlose..."
        Print "  Dein Leben ist verwirkt!  "
        BREAK

    Endif

ENDWHILE

Color 15,0:Print:Print "Nochmal?",:Input i$
case upper$(i$)="J":goto "START"
print "  Danke per das Spiel! Bye!"
waitinput 1500
END