XProfan

Deutsch

Julian
Schmidt

Hallo,
ich würde gerne erfassen ob innerhalb eines bestimmten Bereichs eines Haupt-, oder Dialogfensters eine Links,- Rechts-, Doppel(links)klick gemacht wurde.
Ich weiß das es etwa für Links und Rechtsklick die Messages WM_LButtonDown, WM_RButtonDown gibt. Nur wie ermittle ich einen Doppelklick innerhalb eines bestimmten Bereichs?
Kompilieren Markieren Separieren

Def LinksImBereich(4) (%message=$201) and (%MouseX>@&(1)) and (%MouseX<@&(3)) and (%MouseY>@&(2)) and (%MouseY<@&(4))
Def RechtsImBereich(4) (%message=$204) and (%MouseX>@&(1)) and (%MouseX<@&(3)) and (%MouseY>@&(2)) and (%MouseY<@&(4))
Windowstyle 24
cls
UseBrush 7,RGB(153,153,153)
Rectangle 50,50 - (width(%hwnd)-50),(height(%hwnd)-50)

While 1

    Waitinput

    If LinksImBereich(50,50,width(%hwnd)-50,height(%hwnd)-50)'Links im Innen-Rechteck = Verschieben

        UseCursor 5
        SendMessage(%hwnd,$112,$F012,0)
        External("USER32","ReleaseCapture")
        UseCursor 0

    Elseif RechtsImBereich(50,50,width(%hwnd)-50,height(%hwnd)-50)=0'Rechts im Außen-Rechteck = Ende

        break

    EndIf

Endwhile

LG

Julian57

XProfan X2
Win7 Home Premium, SP1, AMD Athlon(tm) II Neo K125 Processor
˗˗˗˗˗˗˗˗˗˗˗˗˗˗˗˗˗˗˗˗˗˗˗˗˗˗˗˗˗˗˗˗˗˗˗˗˗˗˗˗˗˗˗˗˗˗˗˗˗˗˗˗˗˗˗˗˗˗˗˗
Webseite [...]

24.09.2011 ▲

Vollständiges Zitat

Absatzweise zitieren Zeilenweise zitieren

« Dieser Beitrag wurde als Lösung gekennzeichnet. »

Detlef
Jagolski

Und so mit SubClassing!
Kompilieren Markieren Separieren

 $P+
SetErrorLevel 0
 $H WINDOWS.PH
 $H MESSAGES.PH
 $H STRUCTS.PH
STRUCT TRect         = ~Rect
STRUCT TPoint        = ~Point
Declare appexit%
Declare Point#
Declare Rect#
Declare Punkt&
Dim Point#,TPoint
Dim Rect#,TRect

SubClassProc

    If SubClassMessage(%hwnd, ~WM_LBUTTONDBLCLK)

        Point#.X& = LOWORD(&sLParam)
        Point#.Y& = HIWORD(&sLParam)
        ~SetRect(Rect#,70,70,200,200)
        Case ~PtInRect(Rect#,Point#.X&,Point#.Y&) <> 0: Print "Doppelklick Links"

    ElseIf SubClassMessage(%hwnd, ~WM_RBUTTONDBLCLK)

        Point#.X& = LOWORD(&sLParam)
        Point#.Y& = HIWORD(&sLParam)
        ~SetRect(Rect#,70,70,200,200)
        Case ~PtInRect(Rect#,Point#.X&,Point#.Y&) <> 0: Print "Doppelklick Rechts"

    EndIf

    Set("WinProc",1)

EndProc

SetTrueColor 1
WindowStyle $003F
WindowTitle "DesignForm"
Window %maxX + 5,114 - 498,415
Cls ~GetSysColor(15)
~SetClassLong(%hwnd,~GCL_STYLE,(~GetClassLong(%hwnd, ~GCL_STYLE) + ~CS_DBLCLKS))
Rectangle 70,70 - 200,200
UseFont "MS Sans Serif",13,0,0,0,0
SetDialogFont 1
SubClass %hwnd,1
SetWindowPos %hwnd = 207,114 - 498,415;0

WhileNot appexit%

    WaitInput

    If %key = 2

        appexit%=1

    ElseIf %key = 4

        ' Fenstergröße

    ElseIf %key = 5

        ' Hilfe

    EndIf

Wend

SubClass %hwnd,0
Dispose Point#
Dispose Rect#

XProfan X4, PRFellow, Profan2Cpp - Version 2.0c-pre5, Windows 11

25.09.2011 ▲

Vollständiges Zitat

Absatzweise zitieren Zeilenweise zitieren

Detlef
Jagolski

Aus der API Hilfe!

WM_NCLBUTTONDBLCLK
WM_MBUTTONDBLCLK
WM_RBUTTONDBLCLK
WM_LBUTTONDBLCLK

XProfan X4, PRFellow, Profan2Cpp - Version 2.0c-pre5, Windows 11

24.09.2011 ▲

Vollständiges Zitat

Absatzweise zitieren Zeilenweise zitieren

Julian
Schmidt

Ein Beispiel?

24.09.2011 ▲

Vollständiges Zitat

Absatzweise zitieren Zeilenweise zitieren

Kannst z.B. wm_lButtonDblClk als UserMessage festlegen...

XProfan X2
Win7 Home Premium, SP1, Core(TM)2 Duo E6750 @ 2.66GHz

24.09.2011 ▲

Vollständiges Zitat

Absatzweise zitieren Zeilenweise zitieren

Julian
Schmidt

Also prinzipiell sowas? Funktioniert aber leider nicht.

Kompilieren Markieren Separieren

cls
Usermessages $203

While 1

    Waitinput
    case %UMessage=$203 : messagebox("test","",0)

Endwhile

24.09.2011 ▲

Vollständiges Zitat

Absatzweise zitieren Zeilenweise zitieren

WindowStyle 512 oder SubClassProc...

XProfan X2
Win7 Home Premium, SP1, Core(TM)2 Duo E6750 @ 2.66GHz

25.09.2011 ▲

Vollständiges Zitat

Absatzweise zitieren Zeilenweise zitieren

Julian
Schmidt

Funktioniert aber trotzdem nicht.
Kompilieren Markieren Separieren

cls
Usermessages $203
Subclass %hwnd,1

SubClassProc

    case SubClassMessage(%hwnd, $203) : messagebox("test","",0)

EndProc

While 1

    Waitinput
    case iskey(27) : end

Endwhile

25.09.2011 ▲

Vollständiges Zitat

Absatzweise zitieren Zeilenweise zitieren

Dieter
Zornow

Müsste doch einfach so gehen
Kompilieren Markieren Separieren

Declare X&
Def Getclasslong(2) !"USER32","GetClassLongA"
Def Setclasslong(3) !"USER32","SetClassLongA"
Cls
Usermessages $203,$206
X&=Getclasslong(%Hwnd,-26)
X&=X& | 8
Setclasslong(%Hwnd,-26,X&)'CS_DBLCLKS Class-Style setzen.

While 1

    Waitinput
    Case %Key=2:Break

    If %Umessage=$203

        Print "Linker Doppelklick."

    Elseif %Umessage=$206

        Print "Rechter Doppelklick."

    Endif

Endwhile

Usermessages 0
End

Er ist ein Mann wie ein Baum. Sie nennen ihn Bonsai., Win 7 32 bit und Win 7 64 bit, mit XProfan X2

25.09.2011 ▲

Vollständiges Zitat

Absatzweise zitieren Zeilenweise zitieren

Detlef
Jagolski

Und so mit SubClassing!
Kompilieren Markieren Separieren

 $P+
SetErrorLevel 0
 $H WINDOWS.PH
 $H MESSAGES.PH
 $H STRUCTS.PH
STRUCT TRect         = ~Rect
STRUCT TPoint        = ~Point
Declare appexit%
Declare Point#
Declare Rect#
Declare Punkt&
Dim Point#,TPoint
Dim Rect#,TRect

SubClassProc

    If SubClassMessage(%hwnd, ~WM_LBUTTONDBLCLK)

        Point#.X& = LOWORD(&sLParam)
        Point#.Y& = HIWORD(&sLParam)
        ~SetRect(Rect#,70,70,200,200)
        Case ~PtInRect(Rect#,Point#.X&,Point#.Y&) <> 0: Print "Doppelklick Links"

    ElseIf SubClassMessage(%hwnd, ~WM_RBUTTONDBLCLK)

        Point#.X& = LOWORD(&sLParam)
        Point#.Y& = HIWORD(&sLParam)
        ~SetRect(Rect#,70,70,200,200)
        Case ~PtInRect(Rect#,Point#.X&,Point#.Y&) <> 0: Print "Doppelklick Rechts"

    EndIf

    Set("WinProc",1)

EndProc

SetTrueColor 1
WindowStyle $003F
WindowTitle "DesignForm"
Window %maxX + 5,114 - 498,415
Cls ~GetSysColor(15)
~SetClassLong(%hwnd,~GCL_STYLE,(~GetClassLong(%hwnd, ~GCL_STYLE) + ~CS_DBLCLKS))
Rectangle 70,70 - 200,200
UseFont "MS Sans Serif",13,0,0,0,0
SetDialogFont 1
SubClass %hwnd,1
SetWindowPos %hwnd = 207,114 - 498,415;0

WhileNot appexit%

    WaitInput

    If %key = 2

        appexit%=1

    ElseIf %key = 4

        ' Fenstergröße

    ElseIf %key = 5

        ' Hilfe

    EndIf

Wend

SubClass %hwnd,0
Dispose Point#
Dispose Rect#

XProfan X4, PRFellow, Profan2Cpp - Version 2.0c-pre5, Windows 11

25.09.2011 ▲

Vollständiges Zitat

Absatzweise zitieren Zeilenweise zitieren

Julian
Schmidt

Ok, die beiden Quelltexte funktionieren super!
Besonders die Variante von Detlef

25.09.2011 ▲

Vollständiges Zitat

Absatzweise zitieren Zeilenweise zitieren

iF hats doch geschrieben...WindowStyle 512 oder SubClassProc...

Darauf schreibst Du Funktioniert aber trotzdem nicht in einem Beispiel was weder winstyle 512 oder die Proc nutzt.

Soll man sich schwer an kopf fassen.

25.09.2011 ▲

Vollständiges Zitat

Absatzweise zitieren Zeilenweise zitieren

Julian
Schmidt

Unbenannt (25.09.11)

iF hats doch geschrieben...WindowStyle 512 oder SubClassProc...
Darauf schreibst Du Funktioniert aber trotzdem nicht in einem Beispiel was weder winstyle 512 oder die Proc nutzt.
Soll man sich schwer an kopf fassen.

Wo ist in dem Beispiel kein SubClassProc?

Julian57 (25.09.11)

Kompilieren Markieren Separieren

cls
Usermessages $203
Subclass %hwnd,1

SubClassProc

    case SubClassMessage(%hwnd, $203) : messagebox("test","",0)

EndProc

While 1

    Waitinput
    case iskey(27) : end

Endwhile

So hätte es richtig lauten müssen...
Kompilieren Markieren Separieren

 $H WINDOWS.PH
Usermessages $203
cls
~SetClassLong(%hwnd,~GCL_STYLE,(~GetClassLong(%hwnd, ~GCL_STYLE) + ~CS_DBLCLKS))
Subclass %hwnd,1

SubClassProc

    case SubClassMessage(%hwnd, $203) : messagebox("test","",0)

EndProc

While 1

    Waitinput
    case iskey(27) : end

Endwhile