XProfan

English

Frank has one Anwendungstemplate for a ResHacker provided:

Frank Abbing (07.11.2010)

I have my code something extended, with the The Iconnamen one XProfan-Program gelistet go could. it could now as Base serve, circa a own Resources-editor To write, for all Files, The Resources include. Perhaps has Yes someone pleasure, moreover to develop.

Compile Mark Separation

'
' © Frank Abbing for Paules-PC-Forum
' ./../../sys/?nohdr=1&u=www.paules-pc-forum.de/forum/XProfan/
'
Def EnumResourceNames(4) !"kernel32","EnumResourceNamesA"
Def GetSysColor(1) !"user32","GetSysColor"
Def ExtractIconEx(5) !"shell32.dll","ExtractIconExA"
Def EnumResourceTypes(3) !"kernel32","EnumResourceTypesA"
Declare x&, y&, Text$, hmod&, type&[32], icon&

Proc EnumResNameProc

    Parameters hModule&, lpszType&, lpszName&, lParam&
    Declare name$
    y& = lpszName& >> $10

    Ifnot y&

        name$ = "ID " + Str $(lpszName&)

    Else

        name$ = String $(lpszName&,0)

    Endif

    If name$ <> ""

        x&=TreeView("InsertItem", treeview&, lParam&, 1, name$)
        TreeView("SetChildren", treeview&, lParam&, 1)
        TreeView("Expand", treeview&, lParam&, 2)
        Return 1

    Else

        Return 0

    EndIf

ENDPROC

Proc EnumResTypeProc

    Parameters hModule&, lpszType&, lParam&
    Declare name$
    y& = lpszType& >> $10

    Ifnot y&

        name$ = GetString$(resnames&, lpszType&-1)

    Else

        name$ = String $(lpszType&,0)

    Endif

    If name$ <> ""

        x&=TreeView("InsertItem", treeview&, 0, 0, name$)
        EnumResourceNames(hmod&, lpszType&, ProcAddr("EnumResNameProc", 4), x&)
        Return 1

    Else

        Return 0

    EndIf

ENDPROC

Proc LoadNewFile

    Window Title "Alle Resources List."
    TreeView("DeleteItem", treeview&, 0)
    Text$ = LoadFile $("Datei open:","Ausführbare Dateien|*.EXE;*.DLL;*.CPL;*.SYS;*.SCR;*.OCX;*.AMC")

    If Text$<>""

        Case hmod&: FreeDll hmod&
        hmod& = UseDll(text $)

        If hmod&

            Window Title "Alle Resources List: "+Text$
            SendMessage(treeview&,11,0,0)
            UseCursor 2
            EnumResourceTypes(hmod&, ProcAddr("EnumResTypeProc", 3), 0)
            SendMessage(treeview&,11,1,0)
            UseCursor 0

        Endif

    EndIf

ENDPROC

Window Style 31 + 512
Cls GetSysColor(15)
Var resnames& = Create("List", 0)
AddStrings(resnames&, "Cursor")
AddStrings(resnames&, "Bitmap")
AddStrings(resnames&, "Icon")
AddStrings(resnames&, "Menu")
AddStrings(resnames&, "Dialog")
AddStrings(resnames&, "String")
AddStrings(resnames&, "FontDir")
AddStrings(resnames&, "Font")
AddStrings(resnames&, "Accelerator")
AddStrings(resnames&, "RCData")
AddStrings(resnames&, "MessageTable")
AddStrings(resnames&, "Group_Cursor")
AddStrings(resnames&, "13")
AddStrings(resnames&, "Group_Icon")
AddStrings(resnames&, "15")
AddStrings(resnames&, "Version")
AddStrings(resnames&, "DlgInclude")
AddStrings(resnames&, "18")
AddStrings(resnames&, "PlugPlay")
AddStrings(resnames&, "Vxd")
AddStrings(resnames&, "AniCursor")
AddStrings(resnames&, "AniIcon")
AddStrings(resnames&, "Html")
AddStrings(resnames&, "Manifest")
PopUp "&Datei"
AppendMenu 100,"Laden"
AppendMenu 200,"Beenden"
Var il& = Create("ImageList", 16, 16)
ExtractIconEx("shell32.dll", 4, 0, Addr(icon&),1)
ImageList("AddIcon", il&, icon&)
ExtractIconEx("shell32.dll", 2, 0, Addr(icon&),1)
ImageList("AddIcon", il&, icon&)
Var treeview& = Create("TreeView", %hwnd, il&, 16, 16, 240, 392)
LoadNewFile

While 1

    WaitInput
    Case %key=2: BREAK

    If MenuItem(100)

        LoadNewFile

    ElseIf MenuItem(200)

        BREAK

    Endif

EndWhile

End