XProfan

declare _hLogo%

PROC Init

    declare b#
    '{ 'Image-Handles from hardgecodeten Rohdaten Generate
    DataFile b#,"Test.bmp"'must naturally existieren
    _hLogo%=CatchBmp(b#)
    dispose b#
    '}

ENDPROC'Init

PROC CatchBmp'power a raw eingelesenen BMP-area one anzeigbares Bitmap with a lever

    Parameters MemPointer&'a Memory-Variable, into the BMP binary read watts
    Declare hDC&,BITMAPFILEHEADER#,BMPInfo&,init&,hImage&
    hDC&=@External("user32.dll","GetDC",@External("user32.dll","GetDesktopWindow"))
    'Dim BITMAPFILEHEADER#,14 'I faith, this is superfluously (see under with Dispose BITMAPFILEHEADER#)
    BITMAPFILEHEADER#=MemPointer&
    BMPInfo&=MemPointer&+14
    init&=MemPointer&+Long(BITMAPFILEHEADER#,10)
    hImage&=External("gdi32.dll","CreateDIBitmap",hDC&,BMPInfo&,4,init&,BMPInfo&,0)
    @External("user32.dll","ReleaseDC",@External("user32.dll","GetDesktopWindow"),hDC&)
    'Dispose BITMAPFILEHEADER# 'I faith, this is superfluously and even harmful (it would MemPointer& released and not The original allokierten 14 Bytes)
    Return hImage&

ENDPROC'CatchBmp

cls
init
DrawPic _hLogo%,10,10;0
waitinput
deleteobject _hLogo%
end

STRUCT S_GDIPlusStartupInput=GdiplusVersion&,DebugEventCallback&,SuppressBackgroundThread&,SuppressExternalCodecs&
declare _hPic%,_b#,_b2#,_GDIPlusToken&,_hGDIPlusDll&,_hIcon%,_hShlwapiDll&,_iStream&

PROC InitGDIPlus

    declare gdpsi#,GDIPlusToken&
    _hShlwapiDll&=@usedll("Shlwapi.dll")
    _iStream&=0
    _hGDIPlusDll&=@usedll("GDIPLUS.DLL")
    dim gdpsi#,S_GDIPlusStartupInput
    gdpsi#.GdiplusVersion&=1
    gdpsi#.DebugEventCallback&=0
    gdpsi#.SuppressBackgroundThread&=0
    gdpsi#.SuppressExternalCodecs&=0
    ~GdiplusStartup(@addr(GDIPlusToken&),gdpsi#,0)
    dispose gdpsi#
    return GDIPlusToken&

ENDPROC'InitGDIPlus

PROC DeInitGDIPlus

    parameters GDIPlusToken&
    ~GdiplusShutdown(GDIPlusToken&)
    freedll _hGDIPlusDll&

    if _iStream&

        @external("Shlwapi.dll","IStream_Reset",_iStream&)

    endif

    freedll _hShlwapiDll&

ENDPROC'DeInitGDIPlus

PROC GDIPLoadImageFromFile'is the Vollständigkeit halber dabei; we want Yes but from memory reading

    Parameters Image$
    Declare result&,FileW#,Bitmap&
    result&=0
    dim FileW#,@len(Image$)+2
    widestring FileW#,0=Image$
    ~GdipCreateBitmapFromFile(FileW#,ADDR(Bitmap&))
    dispose FileW#

    if Bitmap&

        result&=Bitmap&

    Endif

    return result&

ENDPROC'GDIPLoadImageFromFile

PROC GDIPlusLoadImageFromMemory'Icons must ditto as normal Graphics (BMP, JPG etc.) transfer go, not as ICO-Files!

    Parameters Image#,ReturnAsAicon%'ReturnAsAicon% can also omitted, then becomes one normales Grafikhandle zurückgegeben
    Declare result&,Bitmap&,hBitmap&,pc%,err%
    pc%=%pcount

    if pc%=1

        ReturnAsAicon%=0

    endif

    result&=0

    if _iStream&=0

        _iStream&=@external("Shlwapi.dll","SHCreateMemStream",Image#,@sizeof(Image#))

    else

        @external("Shlwapi.dll","IStream_Reset",_iStream&)
        @external("Shlwapi.dll","IStream_Write",_iStream&,Image#,@sizeof(Image#))

    endif

    err%=~GdipCreateBitmapFromStream(_iStream&,@addr(Bitmap&))

    if err%<>0

        @messagebox("GdipCreateBitmapFromStream-Error: "+@st$(err%),"",0)

    endif

    if ReturnAsAicon%=0

        err%=~GdipCreateHBITMAPFromBitmap(Bitmap&,@addr(hBitMap&),0)

        if err%<>0

            @messagebox("GdipCreateHBITMAPFromBitmap-Error: "+@st$(err%),"",0)

        endif

    else

        err%=~GdipCreateHICONFromBitmap(Bitmap&,@addr(hBitMap&))

        if err%<>0

            @messagebox("GdipCreateHBITMAPFromBitmap-Error: "+@st$(err%),"",0)

        endif

    endif

    @external("GDIPLUS.DLL","GdipDisposeImage",Bitmap&)

    if hBitmap&

        result&=hBitmap&

    Endif

    return result&

ENDPROC

cls
'~CoInitialize(0) 'evident not necessary
_GDIPlusToken&=@InitGDIPlus()
datafile _b#,"test.jpg"
_hPic%=@GDIPlusLoadImageFromMemory(_b#)
drawpic _hPic%,0,0;0
~deleteobject(_hPic%)
_hIcon%=@GDIPlusLoadImageFromMemory(_b#,1)
drawicon _hIcon%,0,0
~deleteobject(_hIcon%)
dispose _b#
waitinput
DeInitGDIPlus(_GDIPlusToken&)
'~CoUninitialize() 'evident not necessary
end

declare _memsound#

PROC PlayMemSound

    parameters memsound#,synchronous%'synchronous% can also omitted, then becomes 0 as Default taken (means asynchron abgespielt)
    declare p%
    p%:=%pcount

    if p%=1

        synchronous%:=0

    endif

    if synchronous%=0

        @external("Winmm.dll","PlaySoundA",memsound#,0,~SND_MEMORY | ~SND_ASYNC)'see https://learn.microsoft.com/en-us/previous-versions/dd743680(v=vs.85)

    else

        @external("Winmm.dll","PlaySoundA",memsound#,0,~SND_MEMORY | ~SND_SYNC)

    endif

ENDPROC'PlayMemSound

PROC StopSound

    @external("Winmm.dll","PlaySoundA",0,0,~SND_ASYNC)'stop playing

ENDPROC'StopSound

cls
datafile _memsound#,"sound.wav"'must naturally existieren
playmemsound _memsound#
print "fertig."
waitinput
dispose _memsound#
end