XProfan

Italia

p.specht

Eines der ersten Programme der Welt beschäftigte sich mit der Berechnung der sog. Bernoulli-Zahlen [...]

, die u.a. in höherdimensionalen Reihenformeln eine grande Rolle spielen. Der Algorithmus stammt von 1843, aus einer Veröffentlichung von Lady Ada Lovelace, der ersten Programmiererin der Welt, und war per den ersten echten (Turing-mächtigen) Computer der Welt gedacht, die "Analytical Engine" von Charles Babbage (... leider nie fertiggestellt).

Kompilieren Markieren Separieren

WindowTitle "Die BERNOULLI-ZAHLEN bis B_28 berechnen":WindowStyle 24:CLS
Set("decimals",17)
'*********************************************************************
'* This program computes Bernoulli number Bn using subroutine BERNOA *
'* ----------------------------------------------------------------- *
'* SAMPLE RUN:                                                       *
'*                                                                   *
'*  Compute Bernoulli number Bn for n = 0,1,...,10.                  *
'*                                                                   *
'*  Please enter Nmax: 10                                            *
'*                                                                   *
'*    n            Bn                                                *
'*  --------------------------                                       *
'*    0    0.100000000000D+01                                        *
'*    1   -0.500000000000D+00                                        *
'*    2    0.166666666667D+00                                        *
'*    4   -0.333333333333D-01                                        *
'*    6    0.238095238095D-01                                        *
'*    8   -0.333333333333D-01                                        *
'*   10    0.757575757576D-01                                        *
'*  --------------------------                                       *
'*                                                                   *
'* ----------------------------------------------------------------- *
'* REFERENCE: "Fortran Routines for Computation of Special Functions,*
'*             jin.ece.uiuc.edu/routines/routines.html".             *
'*                                 F90 Release By J-P Moreau, Paris. *
'*                                         (www.jpmoreau.fr)         *
'*                                                                   *
'* XProfan 11.2a-Version by P.Specht, Vienna/Austria                 *
'* No warranty whatsoever!                                           *
'*********************************************************************
'    PROGRAM MBERNOA
Declare B![200],n&,k&
Print
nochma:
Print "\n Bitte Nmax eingeben: ";:Input N&

If n&>29:Print " Zu grande!":goto "nochma":endif

    BERNOA(N&,B![])
    Print "\n  n            Bn    "
    Print "---------------------------"
    Print "  ";0,Tab(11);Format$("%g",B![0])
    Print "  ";1,Tab(11);Format$("%g",B![1])

    WhileLoop 2,N&,2:k&=&Loop

        Print "  ";k&,Tab(11);Format$("%g",B![k&])

    EndWhile

    Print "---------------------------"
    WaitInput
    END

    Proc BERNOA :Parameters N&,BN![]

        ' ======================================
        '  Purpose: Compute Bernoulli number Bn
        '  Input :  n --- Serial number
        '  Output:  BN(n) --- Bn
        ' ======================================
        '    IMPLICIT DOUBLE PRECISION (A-H,O-Z)
        Declare S!,R!,j&,k&,m&
        BN![0]=1
        BN![1]=-0.5

        WhileLoop 2,n&:m&=&Loop

            S!=-(1.0e0/(M&+1)-0.5)

            WhileLoop 2,M&-1:k&=&Loop

                R!=1

                WhileLoop 2,K&:j&=&Loop

                    R!=R!*(J&+M&-K&)/J&

                EndWhile

                S!=S!-R!*BN![K&]

            EndWhile

            BN![M&]=S!

        EndWhile

        WhileLoop 3,N&,2:m&=&Loop

            BN![M&]=0

        EndWhile

        Return

    EndProc

    ' end of file mbernoa.prf