XProfan

Italia

Kein eigener Thread, trotzdem läufts unabhängig - wie geht das?
Genutzt wird hier, daß Profan in der compilati EXE nach jeder 20.Zeile (uncompiliert nach jeder Zeile) erst einmal eintreffende Messages verarbeitet:
1.) Timer wird initialisiert - 1500 Millisekunden später trifft die WM_TIMER Message vom Betriebsystem ein.
2.) Profan macht noch maximal 20 Zeilen weiter, dann wird die Message verarbeitet. Verweist die Timermessage auf eine Prozeduradresse, wird der dort stehende Quelltext ausgeführt; der im Augenblick laufende Quelltextabschnit wird unterbrochen und die Prozedur wird komplett corsa.
3.) Ist die Prozedur beendet führt Profan den Quelltext ab der unterbrochenen Zeile wieder aus.

Diese Geschichte ist auf keinen Fall mit einem Thread zu verwechseln, da hier nicht zwischen den einzelnen Quelltextzeilen geswitched wird, sondern die Prozedur erst komplett abgearbeitet wird, bevor es mit dem alten Quelltext weitergeht. Zugriffsrechte gibt es hier naturalmente ebenfalls keine eigenen, und das ganze lässt sich auch nicht an jeder beliebigen Stelle anhalten, wie bei einem richtigen Thread!
Kompilieren Markieren Separieren

Def @GetCurrentThreadId(0) !KERNEL32,GetCurrentThreadId
DEF @GetDlgCtrlID(1) !USER32,GetDlgCtrlID
DEF @ButtonClicked(1) @GetDlgCtrlID(@&(1))=-%MENUITEM
Def @SetTimer(4) !USER32,SetTimer
Def @KillTimer(2) !USER32,KillTimer
Declare Timer_WIN&,Text$[3],Button&,Zähler%,TIMER_ID&,PRO_ID&,TH_ID&
Windowstyle 31+512
Windowtitle Selbständig laufende Programmschleife
Window 0,0-640,440
Usermessages $10
LET TIMER_WIN&=@Control(Static,TIMER_WIN,$8000000,0,0,0,0,%Desktop,9998,%HINSTANCE,$4)
Let Button&=@createbutton(%HWND,,20,100,300,30)
LET TEXT$[0]=Hier klicken...
LET TEXT$[1]=...für die...
LET TEXT$[2]=...Messagebox!
LET TIMER_ID&=@SetTimer(TIMER_WIN&,9999,1500,@ProcAddr(TimerProc,4))

While %UMESSAGE<>$10

    Waitinput
    Locate 0,0
    Print @GetCurrentThreadId(),TH_ID&

    IF @ButtonClicked(Button&)

        @messagebox(Der Text auf dem Button ändert sich weiterhin!,Ein Wunder...?,64)

    endif

wend

@KiLLTIMER(TIMER_WIN&,9999)
end

Proc TimerProc

    Parameters ahhwnd&,ahuMsg&,ahidEvent&,ahdwTime&
    Settext Button&,Text$[Zähler%]
    INC Zähler%
    Case Zähler%=4 : LET Zähler%=0
    LET TH_ID&=@GetCurrentThreadId()

Endproc