XProfan

Declare Handle lb, liste, edit1, btn1, btn2
Declare String pfad, such
Declare Long ende
ende = 0
liste = Create("List", 1)
WindowTitle "Text - Sucher (XProfan-X4 Version von Heinz Brill)"
Window 800, 400
Create("Text", %HWnd, "Suchstring", 10, 10, 90, 25)
edit1 = Create("Edit", %HWnd, "", 100, 10, 180, 25)
btn1  = Create("Button", %HWnd, "Ordner wählen", 10, 60, 120, 25)
btn2  = Create("Button", %HWnd, "Start", 180, 60, 60, 25)
lb    = Create("Listbox", %HWnd, 0, 10, 120, 500, 200)

WhileNot ende

    WaitInput

    If Clicked(btn1)

        pfad = ChooseDir$("Wähle Ordner !")

    ElseIf Clicked(btn2)

        such = GetText$(edit1)

        If pfad <> ""

            CHDIR pfad

        Else

            pfad = $CurrentDir

        EndIf

        If such <> ""

            ClearList liste
            ClearList 0
            Dateisuche()

        Else

            MessageBox("Bitte zuerst Suchstring eintragen", "Fehler", 0)

        EndIf

    EndIf

    Case %Key = 2 : ende = 1

EndWhile

Proc Dateisuche

    AddFiles "*.*"
    Move("ListToHandle", liste)
    ClearList
    ClearList lb
    Set("MoveListMode", 1)

    WhileLoop 0, GetCount(liste) - 1

        IfNot InStr("[", GetString$(liste, &LOOP))

            AddString(lb, GetString$(liste, &LOOP) + "  Datum : " + DToc$(GetFDate$(GetString$(liste, &LOOP))) + "   Zeit : " + GetFTime$(GetString$(liste, &LOOP)))
            Move("FileToList", GetString$(liste, &LOOP))
            AddString(lb, "     ")

        EndIf

    EndWhile

EndProc

MoveListProc
Parameters String s, Int i
Set("RegEx", 1)

If Get("MoveListMode") = 1

    If Match$(such, s) <> ""

        AddString(lb, Str$(i + 1) + ". Zeile    " + s)

    EndIf

EndIf

Set("RegEx", 0)

EndProc