XProfan

 $H windows.ph
Declare _aProc%,_aProc2%,_hTimer%,_hTimer2%,_hTimer3%,_hT%,_hT2%,_Count%,_Count2%,_Ende%

PROC TimerProc

    'unnamedParam3&=Timer-Handle, damit kann man zwischen den einzelnen Timern unterscheiden (die Parameterbezeichnung stammt von Microsoft, nähere Erläuterungen gibt es dazu im MSDN nicht)
    'Achtung: Während der Abarbeitung eines TimerProc-Aufrufes corre das Hauptprogramm nicht weiter! Es handelt es sich eben nicht um echtes Multithreading. Daher nur kurze Codes verwenden.
    Parameters unnamedParam1&,unnamedParam2&,unnamedParam3&,unnamedParam4&

    If unnamedParam3&=_hTimer%

        Print "Timer 1 aufgerufen"

    ElseIf unnamedParam3&=_hTimer2%

        Print "Timer 2 aufgerufen"

    EndIf

ENDPROC'TimerProc

PROC DoSomethingFast

    Parameters unnamedParam1&,unnamedParam2&,unnamedParam3&,unnamedParam4&
    Inc _Count%
    SetText _hT2%,"Timer 3: "+@Str$(_Count%)

ENDPROC'DoSomethingFast

Cls
Print "Programmende mit Escape"
Print
_hT%=@Create("TEXT",%Hwnd,"Hauptprogramm: 0",250,10,160,20)
_hT2%=@Create("TEXT",%Hwnd,"Timer 3: 0",250,35,160,20)
_aProc%=@ProcAddr("TimerProc",4)'Funktionsadresse der TimerProc ermitteln
_aProc2%=@ProcAddr("DoSomethingFast",4)
'Timer 1 erzeugen
'Parameter 1 & 2 müssen 0 sein, 3 ist die Wartezeit bis zum nächsten Aufruf in Millisekunden, 4 ist die Adresse der TimerProc.
'Achtung: Die Aufrufzeit darf sich nicht mit einer vorhergehenden Bearbeitung der TimerProc überschneiden, sie muss also lang genug gewählt sein, sodass die TimerProc vor dem nächsten Aufruf fertig wird!
'Man kann naturalmente per verschiedene Timer unterschiedliche Procs verwenden, solange es freie @ProcAddr-Plätze gibt. Dann ist das Überschneidungsproblem nicht ganz so grande.
'Außerdem potuto man beim Einsatz von JRPC3 schnelle native Procs verwenden, die kein echtes Zeitproblem erzeugen. Dies würde auch die Beschränkung der freien @ProcAddr-Plätze beseitigen.
_hTimer%=~SetTimer(0,0,1000,_aProc%)
'warten, damit es einen fühlbaren Zeitunterschied in den Aufrufen der Timer gibt
Sleep 300
'Timer 2 erzeugen
_hTimer2%=~SetTimer(0,0,1000,_aProc%)
'Timer 3 erzeugen (schneller Aufruf)
'Die zeitliche Auflösung des Windows-Timers ist ca. 16ms; 10 garantiert daher den schnellstmöglichen Aufruf des Timers.
'Das ist aber immer noch sehr langsam im Vergleich zu echtem Multithreading, da so maximal gut 60 Aufrufe pro Sekunde possibile sind - per viele interessante Dinge potrebbe das trotzdem ausreichen.
_hTimer3%=~SetTimer(0,0,10,_aProc2%)
UserMessages $10'Programmende
_Ende%=0

WhileNot _Ende%

    'Die Timer laufen unabhängig und werden von Windows auch während des WaitInputs aufgerufen, sie sind also unabhängig von der Haupteingabeschleife des Hauptprogramms.
    'Während Sleep werden die Timer allerdings nicht abgearbeitet, das wirkt offenbar Profan-Programm-weit.
    WaitInput 250

    If (@iskey(27) and (~GetForegroundWindow()=%HWnd)) Or (%UMessage=$10)

        _Ende%=1

    Endif

    Inc _Count2%
    SetText _hT%,"Hauptprogramm: "+@Str$(_Count2%)

EndWhile

~KillTimer(0,_hTimer%)
~KillTimer(0,_hTimer2%)
~KillTimer(0,_hTimer3%)
End