XProfan

{$FBSYNTAX ON}

declare a%[2]

fbPROC fbArrayTest1(ByVal p As Byte Pointer) As Integer Export
  poke integer,p+0,100 'hier p immer um 4 erhöhen, da p als Byte Pointer definiert ist und FreeBasic daher beim Pointer immer ein Byte weiterzählt
  poke integer,p+4,101 'das entspricht dem intuitiven Vorgehen, wenn man Integers in einen Speicherbereich schreibt
  poke integer,p+8,102
  return 0
ENDPROC

fbPROC fbArrayTest2(ByVal p As Integer Pointer) As Integer Export
  poke integer,p+0,103 'hier p immer nur um 1 erhöhen, da p als Integer Pointer definiert ist und FreeBasic weiß, wie viele Bytes in jedem Element stecken (nämlich 4 pro Integer)
  poke integer,p+1,104 'das ist *nicht* unbedingt intuitiv; ich würde sowas vermeiden und lieber Byte Pointer per Arrays benutzen
  poke integer,p+2,105
  return 0
ENDPROC

cls
fbArrayTest1(@addr(a%[0]))
print a%[0]
print a%[1]
print a%[2]
print
fbArrayTest2(@addr(a%[0]))
print a%[0]
print a%[1]
print a%[2]
waitinput
end

{$FBSYNTAX on}

declare b1#,b2#,b3#,uebergabe#

fbProc fb3Strings(ByVal uebergabe As Any Pointer) As Integer Export
  dim As ZString Pointer s1,s2,s3
  s1=peek(ZString Pointer,uebergabe)
  s2=peek(ZString Pointer,uebergabe+4)
  s3=peek(ZString Pointer,uebergabe+8)
  screenres(400,300)
  print *s1
  print *s2
  print *s3
  return 0
ENDPROC

cls
dim b1#,10000
dim b2#,10000
dim b3#,10000
string b1#,0="String 1"
string b2#,0="String 2"
string b3#,0="String 3"
dim uebergabe#,12
long uebergabe#,0=b1#
long uebergabe#,4=b2#
long uebergabe#,8=b3#
fb3Strings(uebergabe#)
waitinput
dispose uebergabe#,b1#,b2#,b3#
end

{$FBSYNTAX on}

declare a%[10],i%

fbProc fbArrayTest(ByVal p As Any Pointer) As Integer Export
  dim i As Byte
  dim a(10) As Integer Pointer
  for i=0 to 10
    a(i)=p+(i*4) 'Adresse des Elements setzen
    *a(i)=i 'dem Element einen Wert zuweisen
  next i
  return 0
ENDPROC

cls
fbArrayTest(@addr(a%[0]))
for i%,0,10
  print a%[i%]
endfor
waitinput
end

Declare Name$
WindowTitle "BILD-BETRACHTER"
CLS
ShowMax
Name$ = @LoadFile$("Bilddateien","*.BMP")

While Name$ <> ""

    Cls
    LoadBmp Name$,0,0; 0
    WindowTitle "BILD-BETRACHTER - [" + Name$ + "]"
    WaitMouse
    Name$ = @LoadFile$("Bilddateien","*.BMP")

EndWhile

End