XProfan

 {$cleq}
Declare s$
Cls
s$="TEST THE FASTEST XPROFAN"
print s$+"."
print rstr$(s$)+"."
Waitkey
End

proc rstr$

    parameters s$
    declare ss$
    ss$:=s$+" "

    AsmStart _rstr

        Parameters addr(s$),len(s$),addr(ss$)
        .data
        cw dd 0
        .code
        mov eax,para1
        mov ebx,para2
        mov ecx,para3
        mov cw,ebx
        mov edx,0

        .while edx<ebx

            dec cw
            push ebx
            push edx
            mov edx,cw
            mov bl,[ecx+edx]
            pop edx
            mov [eax+edx],bl
            pop ebx
            inc edx

        .endw

    AsmEnd

    return s$

endproc

PRFellow-Vorlage
Autor: Thomas Hölzer
Einen String von hinten nach vorne kehren
Declare strbuf#

Proc ReverseString

    Parameters s$
    Declare l%,result$
    Let l%=Len(s$)
    Dim strbuf#,Add(l%,1)
    String strbuf#,0=s$
    Dec l%

    While Gt(l%,-1)

        Let result$=result$;Char$(strbuf#,l%,1)
        Dec l%

    Wend

    Dispose strbuf#
    Return result$

EndProc

Beispiel
Cls
Declare n&
n&=&gettickcount
ReverseString MkStr$($Syspath + $Winpath,100)
print (&gettickcount - n&) / 1000,Len(MkStr$($Syspath + $Winpath,100))
WaitInput

Proc ReverseStr

    Parameters RS_ES$
    Declare RS_AS$

    WhileLoop Len(RS_ES$),1,-1

        RS_AS$ = (RS_AS$ + Mid$(RS_ES$,&Loop,1))

    EndWhile

    Return RS_AS$

EndProc

**** Beispiel ****
Cls
Print "Orginaltext: Beispielstring"
Print
Print "Reverstext:  " + ReverseStr("Beispielstring")
WaitInput
End

 {$Cleq}
Declare S$
Cls
S$="TEST THE FASTEST XPROFAN"
Print S$+"."
Print ReverseString$(S$)+"."
Waitkey
End

Proc ReverseString$

    Parameters s$

    AsmStart _rstr

        Parameters Addr(s$), Len(s$)
        mov ebx,para1
        mov ecx,para2
        mov edx,para1
        add edx,ecx
        dec edx

        .while edx > ebx

            mov al,[ebx]
            xchg al,[edx]
            mov [ebx],al
            inc ebx
            dec edx

        .endw

    AsmEnd

    Return s$

EndProc

 {$iq}
Declare text$
Declare dummy$
text$="Hier steht nur ein Probetext."
dummy$=Space$(Len(text$))

AsmStart Reverse

    Parameters addr(text$),addr(dummy$)
    invoke revstr,para1,para2

AsmEnd

text$=dummy$
Print text$

CLS
var test$ = "Hallo Roland,wie geht es dir ?"
Print test$
Print ReverseString(test$)
WaitInput

Proc ReverseString

    Parameters s$
    ClearList

    WhileLoop 1, Len(s$)

        Move("StrToList",  substr$(s$, -&LOOP), ""):

    EndWhile

    Return Move("ListToStr", "")

EndProc

End

Proc ReverseString2

    Parameters String s
    Declare String st

    WhileLoop 1, Len(s)

        st = st + Mid$(s, -&LOOP, 1)

    EndWhile

    Return st

EndProc