XProfan

Ragnar
Rehbein

bei mir ist kein buttontext sichtbar.
kann das jemand bestätigen ?

r.r.

Genau, kein Buttontext, ist ja ein Bitmap-Button. Mußt nur darauf achten das du auch ein solch XPROFAN.BMP im Verzeichnis hast, oder einfach auf ein anderes BMP zeigen.

iF

Ragnar
Rehbein

das teeeest hatte mir suggeriert, das grafik + text auf dem button ist.
ich hätte mich gefreut, wenn es auch eine möglichkeit ohne die skcontrol.dll gegeben hätte.

r.r.

Kappier ich irgendwie nich, ein Button ist doch entweder Bitmap, oder Text. Schreib doch den Text auf die Grafik.

Das ginge ja sogar automatisiert (programmiert) das z.B. der Bitmap erst im Speicher(bitmap) generiert wird, und dann auf den But gelegt.

iF

Ragnar
Rehbein

also ich verwende häufig bottons die einen text enthalten und rechts oder links daneben ein icon. einfach weil es nett aussieht.
der text ist bei einigen programmen per ini konfigurierbar.

mit bitmaps wäre der aufwand einen text oder eine buttongröße zu ändern viel größer. außerdem würde das nur klappen wenn ich die bitmap zur laufzeit erstelle, da der button ja zu den gewählen systemfarben passen soll. transparenz wie bei icons ist bei bitmaps wohl nicht possibile. ich müßte also den bereich der in in einem icon transparent ist entsprechend mit einer farbe, die zur systemfarbe harmoniert füllen und den test darauf plazieren.

bisher nutze ich die skcontrol.dll.
diese hat jedoch auch nachteile. ich kann z.b. keine bottonstyles zuweisen.
einen vernünftigen togglebotton zu erstellen, läßt sich nur circa userbottons regeln, wobei ich statt 3 mindestens 4 oder 5 bitmaps bräuchte, wenn ichs nicht nur einrasten sondern auch hovern lassen will.

dabei würde mich ja schon ein kleines niedliches icon auf einem windows-togglebutton glücklich machen.

ich bin bestimmt nicht oberflächenvernarrt, aber ein wenig nett sollte es aussehen und es soll sich leicht ändern lassen.

das ganze sieht dann z.b. so aus:

[img:ce134c3423]https://www.familie-rehbein.de/bild1.JPG[/img:ce134c3423]
sicherlich nicht überragend, aber irgendwie besser als nur buttons.
schnell zu erstellen und schnell zu ändern.
und sie hoovern dank der skcontrol.dll

r.r.

Hmmm, vielleicht einen Buttonkonstrukt circa Subclassing realisieren? Auch ne eigene kleine DLL als 2. Thread potuto leicht erledigen was Du da beschreibst. Es ging mir hier jedoch vordergründig um Bitmap-Buttons, nicht um Icon-Buttons. Ich verstehe jedoch sehr wohl Dein Anliegen, habe aber leider keinen Source parat (oder im Kopf) der Dir da schnell weiterhelfen potuto. Sogern ich Dir da weiterhelfen möchte....:|

Argh, doch, jetzt fällt mir was ein, vielleicht hilft Dir ein Trick, lege ein Bitmap-Static auf dem Button an, so hast Du doch Dein icon. Zwar immernoch ohne Transparents, aber mit einem dünnen Rahmen der nach unten versenkt wirkt, würde das sogar ganz nett aussehen. So hast Du Dein Standart-Button, mit nem Bitmap-Static drauf. Hmmm, obwohl, wenn man dann übers Static hoovern würde potuto man ja nicht auf den Button klicken, hmmm, also auch nicht das wahre.

Bis denne, iF

Uwe
''Pascal''
Niemeier

Hallo Leute!

Ich verwende dafür diese Routine:
Kompilieren Markieren Separieren

window 20,20-500,300
declare dlg&,a&,b&,a#
dim a#,255
 $H Messages.ph
 $H Windows.ph

proc IconButton---------------------------------------------------------------

    parameters Button&,Icon&
    declare bmp&,CDC&,Breite%,Höhe%,Text$,Brush&
    bmp&=sendmessage(Button&,~BM_GETIMAGE,0,0)-Schon Bitmap vorhanden?
    case bmp&:deleteobject bmp&----------------Löschen!
    casenot Icon&:return-----------------------Kein neues Icon? => Ende
    setstyle Button&,$54010080-----------------Style IconButton
    Breite%=width(Button&)
    Höhe%=height(Button&)
    Text$=gettext$(Button&)
    CDC&=~CreateCompatibleDC(%hdc)
    bmp&=~CreateCompatibleBitmap(%hdc,Breite%,Höhe%)
    ~SelectObject(CDC&,bmp&)
    ~SetBkMode(CDC&,~TRANSPARENT)--------------keine Hintergrundfarbe für Text
    Brush&=~GetSysColorBrush(~COLOR_3DFACE)----Hintergrund Systemfarbe
    ~SelectObject(CDC&,Brush&)
    ~Rectangle(CDC&,0,0,Breite%,Höhe%)---------Button mit Systemfarbe füllen
    ~DrawIcon(CDC&,2,2,Icon&)------------------Icon zeichnen (Abstand Rand 2,2)
    clear a#
    long a#,0=34-------------------------------Text beginnt hinter Icon
    long a#,8=Breite%
    long a#,12=Höhe%---------------------------Text wird vert. zentriert => Ganze Höhe angeben
    ~DrawText(CDC&,addr(Text$),len(Text$),a#,~DT_SINGLELINE | ~DT_CENTER | ~DT_VCENTER)
    ~DeleteDC(CDC&)
    deleteobject Brush&
    sendmessage(Button&,~BM_SETIMAGE,0,bmp&)--Bitmap zuweisen
    endproc-----------------------------------------------------------------------
    dlg&=create("dialog",%hwnd,"",200,200,300,300)
    a&=create("Button",dlg&,"Testbutton",110,10,110,40)
    b&=~LoadImageA(%hinstance,"A",~IMAGE_ICON,0,0,~LR_LOADREALSIZE)
    IconButton a&,b&
    waitkey
    b&=~LoadImageA(%hinstance,"Gesicht",~IMAGE_ICON,0,0,~LR_LOADREALSIZE)
    IconButton a&,b&
    waitkey
    IconButton a&,0
    end

Das lässt sich beliebig abwandeln, um z.B. gefärbte Buttons oder Buttons mit farbigem Text und beliebigem Font zu erzeugen (sehr praktisch per ChooseFont-Aufrufe). Oder man potuto den Text unter dem Button Mostra usw.
Nachteilig ist nur, dass man dafür die Grafik-API einsetzen muss. Falls man das Hauptfenster nicht direkt braucht (z.B. weil es von einem rahmenlosen Dialog ausgefüllt wird oder sonstwie unsichtbar ist), kann man seine Buttons auch mit den Profan-Grafikbefehlen entwerfen:
Kompilieren Markieren Separieren

window 20,20-500,300
settruecolor 1
 $H Messages.ph
 $H Windows.ph
declare dlg&,a&

proc DrawButton---------------------------------------------------------------

    parameters Button&,Icon$
    declare bmp&,CDC&,Breite%,Höhe%,Color&,Text$
    bmp&=sendmessage(Button&,~BM_GETIMAGE,0,0)-Schon Bitmap vorhanden?
    case bmp&:deleteobject bmp&----------------Löschen!
    casenot len(Icon$):return------------------Kein neues Icon? => Ende
    setstyle Button&,$54010080-----------------Style IconButton
    Breite%=width(Button&)
    Höhe%=height(Button&)
    Color&=~GetSysColor(15)
    Text$=gettext$(Button&)
    cls-------------mit Standart-Befehlen ins Hauptfenster zeichnen
    usebrush 1,Color&
    usepen 0,1,Color&
    rectangle 0,0-Breite%,Höhe%
    drawicon Icon$,2,2
    textcolor rgb(255,0,0),-1
    drawtext 36,9,Text$
    CDC&=~CreateCompatibleDC(%hdc2)
    bmp&=~CreateCompatibleBitmap(%hdc2,Breite%,Höhe%)
    ~SelectObject(CDC&,bmp&)
    ~BitBlt(CDC&,0,0,Breite%,Höhe%,%hdc2,0,0,$CC0020)
    ~DeleteDC(CDC&)
    sendmessage(Button&,~BM_SETIMAGE,0,bmp&)
    endproc-----------------------------------------------------------------------
    dlg&=create("dialog",%hwnd,"",200,50,300,300)
    a&=create("Button",dlg&,"Testbutton",50,50,120,40)
    DrawButton a&,"A"
    waitkey
    DrawButton a&,"Gesicht"
    waitkey
    DrawButton a&,""
    end

PS: Da lässt sich naturalmente noch vieles verbessern, aber ich bin nun mal kein Freund vorgekauter Lösungen

HTH
Pascal

30.06.2004 ▲