XProfan

WindowTitle "Ersatzformel per Gauß´sches Fehlerintegral, auf 8 Stellen genau"
CLS:font 2:set("decimals",9)
declare mu!,sigma!,x!,x_schon_normiert&,a$,resultat![3]

Repeat

    Print "\n Mittelwert der Grundgesamtheit mu = ";:input mu!
    Print "          Standardabweichung sigma = ";:input sigma!
    Print "   Testwert (Merkmalsausprägung) x = ";:input x!
    a$="":x_schon_normiert&=0:Print " Ist x schon normiert? ";
    input a$:a$=lower$(left$(trim$(a$),1))
    case (a$="j") or (a$="y") or (a$="1") or (a$="+"):x_schon_normiert&=1
    Gausskurvenintegral(mu!,sigma!,x!,x_schon_normiert&)
    'Ergebnisse nun in globaler Variable Resultat![0..3]
    print "\n  x-Wert      Dichte      Wahrscheinl.per: Wert<x        Wert in +\-x \n"+mkstr$("-",75)
    print tab(2);resultat![0];" ";tab(22);resultat![1];" ";tab(42);resultat![2];" ";tab(62);resultat![3]
    print mkstr$("-",75):print

until 0

proc Gausskurvenintegral :parameters mu!,sigma!,x!,x_schon_normiert&

    Resultat![0]=x!'Rückgabearray extern deklariert
    casenot x_schon_normiert&: x!=if(sigma!<>0,(x!-mu!)/sigma!,(x!-mu!))
    declare F!,S2!,Einseitig!,Zweiseitig!
    F!=exp(-0.5*sqr(x!))/2.5066283:S2!=x!:x!=1/(1+0.2316419*abs(x!))
    Resultat![1]=F!
    Einseitig!=1-F!*x!*(0.31938153+x!*(-0.356563782+x!*(1.781477937+x!*(-1.821255978+x!*1.330274429))))
    Resultat![2]=Einseitig!
    case s2!<0:Einseitig!=1-Einseitig!
    Zweiseitig!=abs(1-2*Einseitig!)
    Resultat![3]=Zweiseitig!

endproc