Deutsch
Quelltexte/ Codesnippets

Fenstergröße Begrenzen, MINMAXINFO, WM_GETMINMAXINFO

 

Georg
Teles

Damit lässt sich die Fenstergröße nach Belieben begrenzen - die Message zum Ändern der Position / Größe des Fensters wird aufgefangen, verändert & an das Fenster versendet
'###############################################
'#                                             #
'#  Fenstergröße begrenzen mittels MINMAXINFO  #
'#                                             #
'#          Georg Teles am 27.12.2018          #
'#                                             #
'###############################################
 $H structs.ph
 $H windows.ph
 $H messages.ph
Declare OldWndProc&, ico&, e%
'-------------# Definitionen
Def GetWindowLong(2)!"USER32","GetWindowLongA"
Def SetWindowLong(3)!"USER32","SetWindowLongA"
Def CallWindowProc(5)!"USER32","CallWindowProcA"
Def RtlMoveMemory(3)!"KERNEL32","RtlMoveMemory"
'-------------# Strukturen
'reserviert, keine Verwendung
Struct ptReserved = ptReservedX&, ptReservedY&
'maximale Breite (x) & Höhe (y) beim Maximierten Fenster
Struct ptMaxSize = ptMaxSizeX&, ptMaxSizeY&
'Position links (x) & oben (y) beim Maximierten Fenster
Struct ptMaxPosition = ptMaxPositionX&, ptMaxPositionY&
'kleinste Breite (x) & Höhe (y) beim Vergrößern/Verkleindern des Fensters
Struct ptMinTrackSize = ptMinTrackSizeX&, ptMinTrackSizeY&
'größte Breite (x) & Höhe (y) beim Vergrößern/Verkleindern des Fensters
Struct ptMaxTrackSize = ptMaxTrackSizeX&, ptMaxTrackSizeY&
'MINMAXINFO Struktur
Struct MinMax = ptReserved, ptMaxSize, ptMaxPosition, ptMinTrackSize, ptMaxTrackSize
'Variable für MINMAXINFO
Declare MMI#
Dim MMI#, MinMax
'-------------# CallBack Routine

Proc WindowProc

    Parameters hWnd&, Message&, wParam&, lParam&
    ' alternativ in der Schleife regeln
    'If Message& = ~WM_KEYFIRST ' TASTEN auswertung
    'Case WParam& = 27:~PostQuitMessage(0) 'zB %Key = 27 für ESC
    'Endif

    If Message& = ~WM_GETMINMAXINFO' Message auffangen

        ' Pointer lParam auffangen und MMI füllen
        RtlMoveMemory(MMI#, lParam&, SizeOf(MMI#))
        ' Werte nach Belieben anpassen
        '-------------# Alternative 1

        With MMI#

            .ptMinTrackSizeX& = 355
            .ptMinTrackSizeY& = 282
            .ptMaxTrackSizex& = 500
            .ptMaxTrackSizey& = 500

        Endwith

        '-------------# Alternative 2
        'MMI#.ptMinTrackSizeX& = 355
        'MMI#.ptMinTrackSizeY& = 282
        'MMI#.ptMaxTrackSizex& = 500
        'MMI#.ptMaxTrackSizey& = 500
        ' MMI dem lParam Pointer wieder zuweisen
        RtlMoveMemory(lParam&, MMI#, SizeOf(MMI#))

    EndIf

    ' alternativ in der Schleife regeln
    'If Message& = ~wm_Destroy
    '  ~PostQuitMessage(0)
    'Endif
    Return CallWindowProc(OldWndProc&, hWnd&, Message&, wParam&, lParam&)

EndProc

'-------------# Programm
Set("FastMode",1)
Set("TrueColor",1)
Windowtitle "Fenstergröße Begrenzen"
Window 100,100 - 355,282
ico& = Create("hIcon",Par$(0),0)' Icon erwünscht ?
SendMessage(%HWnd,$80,1,ico&)' Icon setzen
SetWindowLong(%HWnd,-16,$92CE0000)' passenden Style wählen
OldWndProc& = GetWindowLong(%hWnd, -4)' original WndProc speichern
SetWindowLong(%hWnd, -4, ProcAddr("WindowProc",4))' WindowProc zuweisen

WhileNot e%

    Waitinput

    If %Key = 27

        Inc e%

    ElseIf %Key = 2

        Inc e%

    EndIf

EndWhile

SetWindowLong(%hWnd, -4, OldWndProc&)' original WndProc wiederherstellen
DeleteObject ico&
DisPose MMI#

Grüße Georg
 
XProfan X2
TC-Programming [...] 
XProfan 10.0 - XProfan X2 - XProfan X3 - XProfan X4
27.12.2018  
 



Zum Quelltext


Thementitel, max. 100 Zeichen.
 

Systemprofile:

Kein Systemprofil angelegt. [anlegen]

XProfan:

 Beitrag  Schrift  Smilies  ▼ 

Bitte anmelden um einen Beitrag zu verfassen.
 

Themenoptionen

287 Betrachtungen

Unbenanntvor 0 min.
Michael Borowiak07.03.2019
Sascha Haak26.02.2019
p.specht11.02.2019
ByteAttack26.01.2019
Mehr...

Themeninformationen

Dieses Thema hat 1 Teilnehmer:

Georg Teles (1x)


AGB  |  Chat  |  Datenschutz  |  Download  |  Eingangshalle  |  Hilfe  |  Impressum  |  Mart  |  Support  |  Suche

Ein Projekt aller XProfaner, die es gibt!


Mein XProfan
Private Nachrichten
Eigenes Ablageforum
Themen-Merkliste
Eigene Beiträge
Eigene Themen
Zwischenablage
Abmelden
 Deutsch English Français Español Italia
Übersetzungen

Datenschutz


Wir verwenden Cookies nur als Session-Cookies wegen der technischen Notwendigkeit und bei uns gibt es keine Cookies von Drittanbietern.

Wenn du hier auf unsere Webseite klickst oder navigierst, stimmst du unserer Erfassung von Informationen in unseren Cookies auf XProfan.Net zu.

Weitere Informationen zu unseren Cookies und dazu, wie du die Kontrolle darüber behältst, findest du in unserer nachfolgenden Datenschutzerklärung.


einverstandenDatenschutzerklärung
Ich möchte keinen Cookie