XProfan

' gilt ab Windows Vista oder höher
declare Long hShell32, hOle32

proc Init

    hOle32 = ImportDLL("OLE32", "ole.")
    hShell32 = ImportDLL("SHELL32", "shell.")
    ole.CoInitialize(0)

endproc

proc Exit

    ole.CoUnInitialize()
    FreeDLL hOle32
    FreeDLL hShell32

endproc

proc GetCurrentDesktopPath

    declare String KnownFoldersID_Desktop, Long pPath, String desktopPath
    /* Die KnownFolders IDs stehen (mehr oder weniger in Klartext)
    in Microsofts knownfolders.h Headerdatei. Es sind nichts
    Anderes als ein Haufen 16 Byte lange Konstanten. Aus
    ihnen wiederum können die Pfade der verschiedensten
    speziellen Ordner bezogen werden, selbst wenn diese vom
    Nutzer verschoben worden sind.                              */
    KnownFoldersID_Desktop = "\x3A\xCC\xBF\xB4\x2C\xDB\x4C\x42\xB0\x29\x7F\xE9\x9A\x87\xC6\x41"
    shell.SHGetKnownFolderPath(Addr(KnownFoldersID_Desktop), 0, 0, Addr(pPath))
    ' Die obige Funktion hat uns die Adresse eines neu
    ' erzeugten Strings gegeben. Wir basteln daraus
    ' wieder einen XProfan-String.
    desktopPath = StringW$(pPath, 0)
    ole.CoTaskMemFree(pPath)
    return desktopPath

endproc

cls
Init()
print GetCurrentDesktopPath()
Exit()
waitinput
end

Def Desktop(0) ReadIni$("Hkey_1","Software\Microsoft\Windows\CurrentVersion\Explorer\Shell Folders","Desktop")
Print Desktop()
waitinput